source: grammar/dashmarkup.wi @ 5d8653579b142c17f6c0a9c4d36eb89f6e754f6b

#-----------------------------------------------------------------------------
# root productions

document: _empty_line? _paragraph (_empty_line _paragraph)* _document_trailing
;

_document_trailing: _empty_line?
                  | _empty_line
                    NEW_SECTION
                    (_empty_line block_definition)* _empty_line?
;

_empty_line: EMPTY_LINE+
;

_paragraph: heading_paragraph
          | text_paragraph
          | code_paragraph
          | list_paragraph
          | table_paragraph
;

#-----------------------------------------------------------------------------
# common useful productions {{

space: ' '
     | NL
;

_printable: _printable_atom+
;

# anything that can appear on its own and would mean literal text (no
# formatting, no s///, no escape characters \n, no nothing -- just the entered
# text), in order of appearance in lexer
_printable_atom: COMMA
               | STRING
               | Q_CHAR
               | WORD
               | NUMBER
               | PUNCT
               | macro_call
               | macro_call_silent
               | block_call
               | MACRO_VALUE
;

#-----------------------------------------------------------
# macros and %blocks support {{

macro_call: MACRO_CALL ' ' _macro_arguments ']]'
          | MACRO_CALL ' '? ']]'
;

macro_call_silent: MACRO_CALL_SILENT ' ' _macro_arguments ']]'
                 | MACRO_CALL_SILENT ' '? ']]'
;

block_call: BLOCK_CALL ' ' _macro_arguments ']]'
          | BLOCK_CALL ' '? ']]'
;

_macro_arguments: macro_arg (_comma macro_arg)* ' '?
;

_comma: ' ' ' '* COMMA ' '*
      | COMMA ' '*
;

macro_arg: NUMBER
         | STRING
         | MACRO_VALUE
;

# }}}
#-----------------------------------------------------------
# %blocks definition section {{

# XXX: tree postprocessing depends on this static structure:
# BLOCK_CALL, arguments (possibly empty list), body, discard all the rest
block_definition: BLOCK_CALL block_arguments ']]' ' '? '{{{' block_body '}}}'
;

block_arguments: ' ' MACRO_VALUE (_comma MACRO_VALUE)*
               | ' '?
;

# TODO: more paragraphs in the block allowed
block_body: _paragraph
;

# }}}
#-----------------------------------------------------------

_raw_text: _printable (space _printable)*
;

#_raw_text_ending_space: _printable (space _printable)* space?
#;

_non_space_sequence: _non_space_atom+
;

_non_space_atom: _simple_format
               | _printable_atom
;

_text_ending_space: _non_space_sequence (space _non_space_sequence)* space?
;

_text_single_line_must_end_space: (_non_space_sequence ' ')+
;

# }}}
#-----------------------------------------------------------------------------
# text paragraph {{

text_paragraph: text_paragraph_line (LINE_BREAK text_paragraph_line)*
;

text_paragraph_line: _text_ending_space
;

# }}}
#-----------------------------------------------------------------------------
# formatted text {{

_simple_format: bold_text
              | italic_text
              | strike_text
              | tt_text
              | link
              | image
;

link: '[[' link_target ']]'
    | '[[' link_target space link_description ']]'
;

image: '[[!' image_target ']]'
;

link_target: _url
;

image_target: _url
;

_url: _printable
;

link_description: _printable (space _printable)*
                | image space?
;

bold_text: '**' _raw_text '**'
;
italic_text: '__' _raw_text '__'
;
strike_text: '~~' _raw_text '~~'
;
tt_text: '{{' _raw_text '}}'
;

# }}}
#-----------------------------------------------------------------------------
# heading paragraph {{

heading_paragraph: HEADER_S space? _text_ending_space HEADER_E space?
;

# }}}
#-----------------------------------------------------------------------------
# code paragraph {{

# well, nothing fancy: lexer did all the job here
code_paragraph: PRE
;

# }}}
#-----------------------------------------------------------------------------
# numbered/enumerated paragraph {{

list_paragraph: _some_list
;

_some_list: numbered_list
          | alpha_list
          | bullet_list
          | undecorated_list
;

numbered_list: BEGIN_INDENT numbered_list_element+ END_INDENT
;

numbered_list_element: LIST_NUMERIC _list_item _some_list?
;

alpha_list: BEGIN_INDENT alpha_list_element+ END_INDENT
;

alpha_list_element: LIST_ALPHA _list_item _some_list?
;

bullet_list: BEGIN_INDENT bullet_list_element+ END_INDENT
;

bullet_list_element: LIST_BULLET _list_item _some_list?
;

undecorated_list: BEGIN_INDENT undecorated_list_element+ END_INDENT
;

undecorated_list_element: LIST_UNDECO _list_item _some_list?
;

_list_item: list_item_line (LINE_BREAK_INDENTED list_item_line)*
;

list_item_line: _text_ending_space
;

# }}}
#-----------------------------------------------------------------------------
# table paragraph {{

table_paragraph: table_row+
;

table_row: TABLE_ROW_START   table_cell  _trowrest_starting_plain NL
         | TABLE_ROW_H_START header_cell _trowrest_starting_header NL
;

_trowrest_starting_plain: TABLE_CELL   table_cell  _trowrest_starting_plain
                        | TABLE_CELL_R header_cell _trowrest_starting_header
                        | TABLE_ROW_END
;

_trowrest_starting_header: TABLE_CELL_L  table_cell  _trowrest_starting_plain
                         | TABLE_CELL_LR header_cell _trowrest_starting_header
                         | TABLE_ROW_H_END
;

# <td>..</td>
table_cell: _table_cell
;

# <th>..</th>
header_cell: _table_cell
;

_table_cell: ' ' _text_single_line_must_end_space
           | ' '
;

# }}}
#-----------------------------------------------------------------------------